6 :RETURN 
20 CLEAR ;NT=2
30 BC=140
50 CY=8;T=0
80 PRINT "   TRY RULING ANCIENT"
82 PRINT "   **** SUMERIA *****"
83 PRINT "SUCCESSFULLY FOR 10 YRS"
85 FOR W=1TO 2000;NEXT W;CLEAR 
86 O=0;Z=0;P=95;S=2800;H=3000;E=200;Y=3;A=1000;I=5
210 D=0;CLEAR 
218 Z=Z+1;P=P+I-D
219 IF D#0PRINT D," STARVED
220 PRINT I," MOVED TO THE CITY
230 PRINT P," INHABITANTS
232 PRINT A," ACRES AVAILABLE
235 PRINT Y," BU/AC HARVESTED"
250 IF E#0PRINT E," BU EATEN BY RATS
255 IF T>0PRINT T," BU ROTTED
260 PRINT S," BU ON HAND"
261 PRINT ;IF Z=11GOTO 862
310 Y=RND (11)+17
313 PRINT "YEAR",#4,Z
315 PRINT Y," BU BUYS 1 ACRE"
320 INPUT "BUY HOW MANY ACRES?"Q
322 IF Q<0GOTO 320
323 IF Y×Q<=SGOTO 330
324 GOSUB 710;GOTO 320
330 IF Q=0GOTO 340
331 A=A+Q;S=S-Y×Q;GOTO 410
340 INPUT "SELL HOW MANY ACRES?"Q
342 IF Q<0GOTO 340
343 IF Q<AGOTO 350
344 GOSUB 720;GOTO 340
350 A=A-Q;S=S+Y×Q
410 INPUT "SAVE # BU FOR FOOD?"Q
412 IF Q<0GOTO 410
420 IF Q<=SGOTO 430
430 S=S-Q
440 INPUT "SEED # ACRES?"D
442 IF D=0GOTO 511
443 IF D<0GOTO 440
445 IF D<=AGOTO 450
446 GOSUB 720;GOTO 440
450 IF D<=S×2GOTO 455
452 GOSUB 710;GOTO 440
455 IF D÷10<=PGOTO 510
460 PRINT "YOU'VE ONLY GOT ",#1,P
465 PRINT "FIELDHANDS...NOW,
470 GOTO 440
510 S=S-(D÷2)
511 Y=RND (6)+1;H=D×Y
512 IF Y=2PRINT "DROUGHT
513 IF Y=7PRINT "BUMPER CROP
521 C=RND (6)+1;E=S÷C;S=S-E+H
533 C=Q÷20
534 I=RND (20)
535 N=P+I
539 IF S<=5000T=0
540 IF S>5000T=RND (500);S=S-T
545 IF P<C-20PRINT "PEOPLE ARE GETTING FAT!
550 IF P<CGOTO 210
552 D=P-C;IF 100×D>P×45GOTO 560
555 O=O+D
557 GOTO 859
560 PRINT ;O=O+D
561 PRINT "YOU STARVED ",#1,D," PEOPLE!";GOTO 940
710 PRINT "THINK...YOU ONLY HAVE
711 PRINT #1,S," BU OF GRAIN!
712 RETURN 
713 GOTO 410
720 PRINT "THINK...YOU'VE ONLY GOT
725 PRINT #1,A," ACRES!";RETURN 
859 PRINT ;PRINT "SO FAR, ",
862 PRINT #1,O," STARVED!
865 L=A÷(N-D)
870 PRINT "YOU HAVE ",#1,L," ACRES/PERSON
874 IF Z<11GOTO 218
875 PRINT "FROM AN INITIAL 10 ACRES/ PERSON
879 PRINT 
885 IF L<5GOTO 975
892 IF L<8GOTO 957
895 IF (L<10)+(O>0)GOTO 960
900 PRINT "         GREAT!
901 PRINT 
902 PRINT "       YOU WIN!
903 PRINT 
905 PRINT "   >>> ********* <<<
906 FOR T=1TO 3000;NEXT T;GOTO 20
940 PRINT "BOO!!!!"
955 GOTO 975
957 PRINT "YOU HAD BETTER TRY ANOTHER    LINE OF WORK!";GOTO 903
960 PRINT "NOT BAD, NOT BAD!"
970 IF O>50PRINT "BUT YOU STARVED A LOT OF  PEOPLE!
972 GOTO 903
975 PRINT "THAT WAS BAD!"
980 IF O=0PRINT "YOU DIDN'T STARVE ANYONE, BUT ",
990 PRINT "YOU LOSE!!!"
994 NT=10
995 FC=140
997 PRINT "5050550+60660550+45000"
999 CLEAR ;FC=0;GOTO 906
>RUN 
